; docformat = 'rst'

;+
; Text to include afer a markup node of the given type.
;     
; :Private:
; :Returns: string
;
; :Params:
;    type : in, required, type=string
;       type of MGtmNode
;
; :Keywords:
;    newline : out, optional, type=boolean, default=0
;       set to a named variable to get whether a newline should be added at the 
;       given node
;    tag : in, required, type=object
;       tag's object reference
;-
function mgtmhtml::_preTag, type, newline=newline, tag=tag
  compile_opt strictarr

  case type of
    '': return, ''
    'bold': return, '<bold>'
    'bullet_list': return, '<ul>'
    'comments': return, '<span class="comments">'
    'emphasis': return, '<em>'
    'image': begin
        src = tag->getAttribute('source')
        return, '<img src="' + src + '"/>'
      end
    'link': begin
        href = tag->getAttribute('reference')
        return, '<a href="' + href + '">'
      end
    'listing': return, '<code class="listing">'
    'list_item': return, '<li>'
    'newline': begin
        newline = 1
        return, ''
      end
    'numbered_list': return, '<ol>'
    'paragraph': return, '<p>'
    else : return, ''
  endcase
end


;+
; Text to include after a markup node of the given type.
;     
; :Private:
; :Returns: string
;
; :Params:
;    type : in, required, type=string
;       type of MGtmNode
;
; :Keywords:
;    newline : out, optional, type=boolean, default=0
;       set to a named variable to get whether a newline should be added at the 
;       given node
;    tag : in, required, type=object
;       tag's object reference
;-
function mgtmhtml::_postTag, type, newline=newline, tag=tag
  compile_opt strictarr

  case type of
    '': return, ''
    'bold': return, '</bold>'
    'bullet_list': return, '</ul>'
    'comments': return, '</span>'
    'emphasis': return, '</em>'
    'image': return, ''
    'link': return, '</a>'
    'listing': return, '</code>'
    'list_item': return, '</li>'
    'newline': return, ''
    'numbered_list': return, '</ol>'
    'paragraph': begin
        newline = 1
        return, '</p>'
      end
    else: return, ''
  endcase
end


;+
; Define MGtmHTML class for processing HTML.
;-
pro mgtmhtml__define
  compile_opt strictarr

  define = { mgtmhtml, inherits mgtmlanguage }
end